ASP - IIsMimeMap

IIsMimeMap

Объект IIsMimeMap служит для установки наследуемых сопоставлений MIME (Multipurpose Internet Mail Extensions), используемых веб-серверами.

Объект IIsMimeMap является объектом ADSI, но не объектом-контейнером ADSI.

ADsPath

IIS://имя_компьютера/MIMEMAP

где имя_компьютера может быть любым именем или строкой "LocalHost".

Синтаксис

результат = объект.метод

Обозначения

результат

Переменная, получающая значение, возвращаемое методом.

объект

Переменная, содержащая объект IIsMimeMap. Обычно это результат предшествующей операции GetObject.

метод

Выбранный метод объекта.

Свойства

Свойства метабазы

Методы

Пример программы

<% 
  Dim MimeMapObj, aMimeMap, MMType, MMExtension, i, aMimeMapNew() 
  Const ADS_PROPERTY_UPDATE = 2 
'Получение объекта сопоставления MIME. 
  Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap") 
'Получение сопоставлений из свойства MimeMap. 
  aMimeMap = MimeMapObj.GetEx("MimeMap") 
' Вывод сопоставлений. 
  ShowMM(MimeMapObj) 
' Добавление нового сопоставления. 
  i = UBound(aMimeMap) + 1 
  Redim Preserve aMimeMap(i) 
  Set aMimeMap(i) = CreateObject("MimeMap") 
  aMimeMap(i).Extension = ".jnq" 
  aMimeMap(i).MimeType = "junque/my-junque" 
  MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", aMimeMap 
  MimeMapObj.SetInfo 
' Вывод сопоставлений. 
  ShowMM(MimeMapObj) 
'Удаление сопоставления путем копирования в новый массив сопоставлений. 
  i = 0 
  For Each MMItem in aMimeMap 
    If MMItem.Extension <> ".jnq" Then 
      Redim Preserve aMimeMapNew(i) 
      Set aMimeMapNew(i) = CreateObject("MimeMap") 
      aMimeMapNew(i).Extension = MMItem.Extension 
      aMimeMapNew(i).MimeType = MMItem.MimeType 
      i = i + 1 
    End If 
  Next 
  MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", aMimeMapNew 
  MimeMapObj.SetInfo 
'Вывод сопоставлений. 
  ShowMM(MimeMapObj) 
'Подпрограмма вывода сопоставлений в таблице. 
  Sub ShowMM(MMObj) 
  aMM = MMObj.GetEx("MimeMap") 
'Подготовка таблицы для вывода сопоставлений. 
  Response.Write "<HR><TABLE BORDER><CAPTION><B>Сопоставления MIME</B></CAPTION>" 
  Response.Write "<TR><TH>Тип</TH><TH>Расширение</TH>" 
'Вывод сопоставлений в таблице. 
  For Each MM in aMM 
    Response.Write "<TR><TD>" & MM.MimeType & "</TD>" 
    Response.Write "<TD>" & MM.Extension & "</TD></TR>" 
  Next 
  Response.Write "</TABLE>" 
  End Sub 
%>