Автоматизация работы с использованием Windows Scripting Host

Помните ВАТ-файлы DOS? Это было прекрасное средство автоматизации повторяющихся задач. Windows, увы, не предложила эквивалентной замены, а средства сторонних разработчиков не прижились по различным причинам. Но положение, похоже, может исправиться. Windows Scripting Host (WSH) - новый, независимый от языка скрипт-хост для Win9x и NT, позволяет строить аналоги ВАТ-файлов на Visual Basic Scripting Edition, JScript и других скриптовых языках, например, Active Perl или Python.

Здесь мы обсудим некоторые преимущества Windows Scripting Host.

Преимущества Windows Scripting Host

Раньше единственным поддерживаемым Windows скриптовым языком был командный язык DOS. Но его возможности довольно бедны по сравнению с VBScript и JScript. Хотя командный язык DOS по прежнему поддерживается, современные ActiveX-скрипты позволяют решать более сложные задачи.

Cкрипт может принимать решения на основе использования полноценных операторов If/Else. Сценарий может выполнять один набор команд, если данное условие истинно, или другой набор, если условие ложно. Кроме того, JScript и VBScript хороши при выполнении математических операций, включая общие тригонометрические функции.

Другое свойство Windows Scripting Host заключается в том, что скрипты могут исполняться вне браузера. Достаточно кликнуть по файлу с текстом скрипта или ввести его название в командной строке,чтобы запустить его на исполнение. Windows Scripting Host не требователен к памяти и прекрасно годится для автоматизации Windows.

Хост и скриптовые машины

Как ни хороши скриптовые языки, многого с ними не сотворишь. Они неспособны повлиять на что-либо за пределами родного скрипта. Эти языки не имеют прямых инструкций, позволяющих читать или записывать файлы на диске, выводить информацию в командную строку, изменять записи в Реестре Windows и так далее.

Чтобы справиться с такими задачами, можно воспользоваться дополнительными COM-объектами. Ряд таких объектов входит в поставку WSH, а один из них, WScript, даже уже имеет созданный экземпляр, и им можно пользоваться непосредственно, без предварительного создания. Остальные создаются с помощью синтаксиса, соответствующего конкретному языку или функции WScript.CreateObject.

Объекты WSH

В поставку Windows Scripting Host входят 4 объекта: Wscript, WshShell, WshNetwork, и FileSystemObject.

Каждый объект, естественно, имеет набор собственных методов и свойств.

Объект Wscript позволяет скриптам "познать самих себя". Вдобавок этот объект позволяет скриптам запускать приложения и управлять ими. Основные свойства и методы этого объекта перечислены в таблице 1.

Таблица 1. Методы и свойства объекта WScript

Объект WshShell позволяет скриптам устанавливать и конфигурировать другие приложения. Он также дает возможность общаться с пользователем, изменять Реестр и находить папки. Некоторые его свойства и методы перечислены в таблице 2.

Set WSHShell = CreateObject("WScript.Shell")
Set WshSysEnv = WshShell.Environment("Process")
WScript.Echo WshSysEnv("windir")

Таблица 2. Свойства и методы объекта WshShell

Объект WshNetwork используется при создании скриптов, модифицирующих конфигурацию сети. Это включает задачи типа подключения к сети, инсталляцию принтеров, назначение буквенных обозначений сетевым дискам и так далее. Основные свойства и методы WshNetwork перечислены в таблице 3.

Таблица 3. Свойства и методы объекта WshNetwork

Последний объект, FileSystemObject, нужен для дисковых операций. Это включает чтение, запись, удаление файлов и создание каталогов.

FileSystemObject имеет методы BuildPath, CopyFile, CopyFolder, CreateFolder, CreateTextFile, DeleteFile, DeleteFolder, DriveExists, FileExists, FolderExists, GetAbsolutePathName, GetBaseName, GetDrive, GetDriveName, GetExtensionName, GetFile, GetFileName, GetFolder, GetParentFolderName, GetSpecialFolder, GetTempName, MoveFile, MoveFolder, OpenTextFile. Их названия в отдельном объяснении не нуждаются. Его единственное свойство Drives возвращает список дисков, доступных на данной машине, включая сетевые.

Что вам нужно для начала

Первое, что надо сделать - убедиться, что Windows Scripting Host у вас есть. В состав W2K он входит изначально. Если вы используете Windows 98 или Internet Information Server 4.0, или если вы устанавливали Option Pack для Windows NT 4 и для Windows 95, он у вас точно есть. В случае Windows 95 все усложняется, и Windows Scripting Host придется скачивать с сайта Microsoft (msdn.microsoft. com/ scripting). Напишите в командной строке wscript. Если появилось диалоговое окно с надписью, отличной от "File not found", все в порядке.

Microsoft не поставляет визуального редактора скриптов WSH. Но Notepad вполне годится.

Создание и запуск скриптов

По сравнению с различными программистскими изысками писать скрипты для Windows Scripting Host относительно просто. В Notepad вы пишете свой скрипт с использованием упомянутых объектов. Потом сохраняете файл с расширением .vbs для VBScript или .js для JScript.

Запуск скриптов - тоже несложная задача. Есть несколько способов. Самый простой - командная строка DOS и аналогичная версия Windows Scripting Host, CSCRIPT.ЕXE. Эта версия позволяет контролировать исполнение скрипта с помощью параметров командной строки.

Параметры хоста включают или отключают различные опции Windows Scripting Host и всегда предваряются двумя слэшами (//). Имя скрипта - это всегда имя файла, а параметры скрипта - параметры, передаваемые скрипту. Эти параметры всегда предваряются одним слэшем (/). Таблица 4 содержит некоторые параметры CSCRIPT.EXE.

Microsoft (R) Windows Scripting Host Version 5.0 for Windows
Copyright (C) Microsoft Corporation 1996-1997. All rights reserved.

Таблица 4. Параметры командной строки CSCRIPT.EXE

Если вы не желаете видеть окошек с кнопкой ОК, используйте cscript.exe, а для вывода сообщений пользуйтесь методом WScript.Echo.

Для запуска скриптов с помощью wscript.exe имеются три пути.

Один из них - просто дважды щелкнуть по файлу или иконке. Другой - выбрать Выполнить... из меню Пуск и написать полное имя файла в текстовом поле Открыть. Наконец, можно запустить сам WSCRIPT.EXE из того же Выполнить..., добавив к нему имя скрипта и любой из возможных параметров.

Пример скрипта

Попробуем написать какой-нибудь скрипт на VBScript. Конкретный пример, приведенный в Листинге 1, предоставлен Microsoft и может быть получен (как и несколько других) с их WWW-сайта: msdn.microsoft.com/scripting/windowshost/download/default.htm.

Листинг 1

' Этот пример показывает, как использовать объект WSHShell 
' для создания ярлыка на Рабочем столе.

L_Welcome_MsgBox_Message_Text   = _
    "Этот скрипт создаст ярлык для Notepad на Рабочем столе."
L_Welcome_MsgBox_Title_Text     = "Пример Windows Scripting Host "
Call Welcome()

' *************************************************************** *
' * Методы, связанные с ярлыками.
' *DimWSHShell
Set WSHShell = WScript.CreateObject("WScript.Shell")

Dim MyShortcut, MyDesktop, DesktopPath

' Читаем путь к Рабочему столу
DesktopPath = WSHShell.SpecialFolders("Desktop")

' Создаем ярлык на Рабочем столе
Set MyShortcut = WSHShell.CreateShortcut(DesktopPath & _
    "\Shortcut to notepad.lnk")

' Задаем свойства объекта-ярлыка и сохраняем их
MyShortcut.TargetPath = WSHShell.ExpandEnvironmentStrings _
    ("%windir%\notepad.exe")
MyShortcut.WorkingDirectory = WSHShell.ExpandEnvironmentStrings _
    ("%windir%")
MyShortcut.WindowStyle = 4
MyShortcut.IconLocation = WSHShell.ExpandEnvironmentStrings _
    ("%windir%\notepad.exe, 0")
MyShortcut.Save

WScript.Echo "Теперь на Рабочем столе есть ярлык для Notepad."

' ****************************************************************
' *
' * Добро пожаловать
' *
Sub Welcome()
    Dim intDoIt

    intDoIt =  MsgBox(L_Welcome_MsgBox_Message_Text, _
        vbOKCancel + vbInformation, _
        L_Welcome_MsgBox_Title_Text )
    If intDoIt = vbCancel Then
       ;WScript.Quit
    End If
End Sub

Этот скрипт создает на рабочем столе ярлык для Notepad. Замечу, что сейчас в наши задачи не входит обучение пользователя программированию на VB или Java. Тем не менее, этот пример даст вам представление о том, что Windows Scripting Host может делать при наличии некоторых базовых навыков программирования.

Теперь пора перейти к более существенным применениям WSH. Наверное, больше всего WSH пригодится администраторам, осатаневшим от регулярного повторения одних и тех же действий. Администраторы Windows NT не располагали возможностями UNIX-администраторов, использовавших скрипты испокон веков. С появлением WSH ситуация изменилась, тем более, что WSH позволяет воспользоваться внешними по отношению к скриптовым языкам технологиям, таким, как Windows Management Instrumentation (WMI) и Active Directory Services Interface (ADSI).

WMI и ADSI мы будем использовать, я предполагаю, что у вас есть по крайней мере общее понимание этих технологий. Больше информации о них вы можете получить по адресам http://msdn.microsoft.com/developer/sdk/wmisdk/default.asp и http://www.microsoft.com//adsi/

В этих примерах предполагается, что вы используете W2K, для других платформ, вам, вероятно, придется установить WMI и ADSI.

Использование WSH и WMI для создания Logon-скриптов

Как вы знаете, такие скрипты подразумевают запуск в момент старта. В Листинге 2 приведен загрузочный скрипт, который определяет тип входящего в систему пользователя и выполняет задачи, основываясь на этой информации.

Листинг 2

<job>
<script language="vbscript">
on error resume next

set wshNetwork = WScript.CreateObject( "WScript.Network")
Set wshShell = WScript.CreateObject("WScript.Shell")

do while wshNetwork.username = ""
WScript.Sleep 250
loop

user = wshNetwork.username
domain = wshNetwork.userdomain

Wscript.echo "Logging on " & ucase(domain) & "\" & user & "..."

' используя ADSI получаем список групп, в которые входит пользователь
adspath = "WinNT://" & domain & "/" & user
set adsobj = GetObject(adspath)

' Вызов других подпрограмм based on the Windows NT group of the user
for each prop in adsobj.groups
    select case prop.name
        case "Administrators"
            call Adminslogon
        case "YourNewGroup"
            call YourNewGrouplogon
    end select
next
</script>
</job>

Первое, скрипт создает некоторые общие объекты которые вам придется использовать, например, объекты WScript.Network и WScript.Shell. Дальше он использует эти объекты для определения имени пользователя и доменной информации. Наконец, используя ADSI скрипт возвращает информацию содержащую группу пользователя. Эта информация используется для определения подходящей подпрограммы, вызываемой для каждой из пользовательских групп. Это выполняет оператор Select Case.

Загрузочный скрипт для пользователей создаваемой нами группы Windows NT (под именем YourNewGroup) использует сетевые возможности WSH. Он проверяет, используется ли буква Z. Если она свободна, диском Z назначается \\yourserver\NETLOGON используя формат \\server\share.

Чтобы объяснить, как работает загрузочный скрипт, некоторые подпрограммы и функции вынесены в текст статьи. Можете просто вернуть их на место в блок <script> в Листинге 2.

 sub Domainlogon
     if CheckNetworkMapping("z:", "\\yourserver\NETLOGON") = false then
         MapNetwork "z:", "\\yourserver\NETLOGON "
     end if
 end sub

Функция CheckNetworkMapping перечисляет различные буквы дисков чтобы определить, используется ли данная буква (см. Листинг 3). Она возвращает true или false на основании доступности данной буквы. В случае true вызывается подпрограмма MapNetwork для выполнения отображения. Эта подпрограмма использует метод MapNetworkDrive объекта wshNetwork для присвоения сетевому ресурсу соответствующей буквы. Более полную информацию о объекте wshNetwork можно получить из таблицы 3.

Листинг 3

' проверяем наличие сетевого диска, в случае отсутствия добавляем

' Эта функция проверяет наличие сетевого диска
Function CheckNetworkMapping(DriveLetter)
    Dim Drive
    WScript.Echo "Проверяем наличие подключенного сетевого диска " & DriveLetter
    CheckNetworkMapping = False
    For Each Drive In wshNetwork.EnumNetworkDrives
        If LCase(Drive) = LCase(DriveLetter) Then
            CheckNetworkMapping = True
            Exit For
        End If
    Next
    If CheckNetworkMapping Then
        WScript.Echo "Сетевой диск найден"
    Else
        WScript.Echo " Сетевой диск не найден"
    End If
End Function

' Эта подпрограмма ассоциирует букву с сетевым каталогом 
sub MapNetwork(driveletter, netshare)
    on error resume next
    err.clear

    WScript.Echo "Подключаем сетевой диск."
    wshNetwork.MapNetworkDrive driveletter, netshare, true

    if err <> 0 then
        'Подключение не удалось
        WScript.Echo "не могу ассоциировать " & driveletter & " с " & netshare
    else
        WScript.Echo "ОК..."
    end if
end sub

Администраторы могут захотеть получить более детальную информацию, чем описание сетевых ресурсов и пользовательской среды. Им может потребоваться информация о компьютере, например, переменные среды, конфигурация компьютера, аппаратные устройства и так далее. Используя только объектную модель WSH следующий код покажет вам как вывести некую информацию о среде и реестре вашего компьютера.

 sub Adminslogon
      Wscript.Echo _
       "Эта процедура возвращает значения основных переменных среды данного компьютера."
 ReturnENV
 Wscript.Echo
     regProxy
     Wscript.Echo
     'Для работы следующих двух строк требуется ввести сервер, имя пользователя и пароль
     Wscript.Echo "IP-адреса этого компьютера: " & GetIPAddress _ 
         ("yourserver ", "administrator", "p-word")
     Wscript.Echo "Общее количество RAM на этой машине: " & GetRAM _
         ("yourserver ", "administrator", "p-word")
 end sub

Этот скрипт приведен чисто для примера - легкомысленно было бы хранить пароль администратора в открытом виде.

Что же еще можно сделать с помощью объектов, поставляемых вместе с WSH? Например, вы можете получить некую информацию о вашем компьютере. Это можно сделать с помощью метод ReturnENV. Сперва в этом методе потребуется подключить wshProcEnv к рабочей среде. Перед этим нужно создать объект wshShell (см. скрипт ниже). Как только вы подключились к окружению процесса, вы можете вернуть данные наподобие NUMBER_OF_PROCESSORS или PATH конфигурации данного компьютера. Здесь несколько примеров того, что вы можете извлечь из окружения процесса.

sub ReturnENV()
     set wshShell = Wscript.CreateObject("WScript.Shell")
     set wshProcEnv = wshShell.environment("process")
 
     WScript.Echo ("NUMBER_OF_PROCESSORS: " & wshProcEnv _ 
         ("NUMBER_OF_PROCESSORS"))
     WScript.Echo
     WScript.Echo ("PROCESSOR_IDENTIFIER: " & wshProcEnv _
         ("PROCESSOR_IDENTIFIER"))
     WScript.Echo
     WScript.Echo ("OS: " & wshProcEnv ("OS"))
     WScript.Echo
     WScript.Echo ("PATH: " & wshProcEnv ("PATH"))
     WScript.Echo
     WScript.Echo ("WINDIR: " & wshProcEnv ("WINDIR"))
     WScript.Echo
end sub

Заметьте, что этот скрипт полностью работоспособен только в среде NT (или W2K). В WindowsК9x будут доступны только PATH и WINDIR.

Вы, несомненно, знаете, что неумелыми, а тем более умелыми действиями в реестре можно быстро и бесповоротно угробить любую ОС от Microsoft. Для автоматизации этого процесса WSH предоставляет простой способ управления реестром. Методами RegRead, RegWrite и RegDelete вы можете сделать все, что заблагорассудится. Все, что требуется - указать верный ключ для чтения, записи или удаления.

Попробуем для примера настроить proxy-сервер. Получить текущую информацию, хранящуюся в реестре по адресу HKCU\Software\Microsoft\ Windows\CurrentVersion\Internet Settings\ProxyServer можно с помощью метода RegRead. Затем, используя RegWrite, перепишем это значение собственным, именем какого-то вашего proxy-сервера, MYPROXY:80. Наконец, убедимся, что записали верную информацию, для чего снова считаем значение с помощью RegRead.

sub regProxy
     prefix =  "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\"
 
     WScript.Echo "Старые установки Proxy-сервера: " & wshShell.RegRead(prefix & _
         "ProxyServer")
     wshShell.regWrite prefix & "ProxyServer", "MYPROXY:80"
     WScript.Echo  " Новые установки Proxy-сервера: " & wshShell.RegRead(prefix & _
         "ProxyServer")
 end sub

С помощью WMI вы можете собрать массу интересных сведений. Функция GetIPAddress использует WMI для определения IP-адреса машины. Здесь я не буду вдаваться в детали WMI, но, в основном, команда GetObject берет объект управления WMI. Этот объект содержит метод ExecQuery, который берет текстовый аргумент, описывающий IP-адрес и возвращает набор всех IP-адресов машины.

GetRAM очень похож на GetIPAddress за исключением того, что запрашиваемые строки различны. Как и в предыдущем случае, в связанном сервисном объекте WMI работает ExecQuery. Листинг 4 показывает реализацию GetIPAddress и GetRAM.

Листинг 4

function GetIPAddress (server, username, password)
    set objLocator = WScript.CreateObject("WbemScripting.SWbemLocator")
    set objService = objLocator.ConnectServer (server, "", username, password)
    strQuery = _
      "Select IPAddress from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE"

    set objEnumerator = objService.ExecQuery(strQuery)

    for each obj in objEnumerator
        if Not IsNull(obj.IPAddress) then 
            for i=LBound(obj.IPAddress) to UBound(obj.IPAddress)
                GetIPaddress = obj.IPAddress(i)
            next
        end if
    next
end function

function GetRAM (server, username, password)
    set objLocator = WScript.CreateObject("WbemScripting.SWbemLocator")
    set objService = objLocator.ConnectServer (server, username, password)
    strQuery = "Select TotalPhysicalMemory From Win32_LogicalMemoryConfiguration"

    set objEnumerator = objService.ExecQuery(strQuery)

    for each obj in objEnumerator
        GetRam = obj.totalPhysicalMemory
    next
end function

Чтобы завершить скрипт, сохраните код в файл logon.wsf (или другой, как хотите). Его следует поместить в \\server\NETLOGON. Это каталог, который Windows NT будет использовать в поисках файлов типа загрузочных скриптов. Заметьте, что не-W2K-серверы могут не исполнять иных файлов, кроме командных и ВАТ-файлов. В этом случае вам придется написать простой logon.bat, который вызывает cscript.exe.

Возможно, будет мудро заменить две функции WMI из Листинга 4 на Windows Script Components.

WSH и Active Directory Service Interfaces (ADSI)

Active Directory работает под Windows 2000. Но клиентские приложения, в нашем случае - скрипты, могут быть запущены и из-под Windows 95, Windows 98 или Windows NT 4.0. Для всех этих ОС существуют клиентские компоненты, которые, как и важную дополнительную информацию, можно получить с WWW-сайта MSDN (см. адрес выше).

Теперь, когда у вас есть загрузочный скрипт, осталось понять, зачем он вам нужен? Представьте, что вам нужно создать 5000 учетных записей пользователей вашей компании, причем, как обычно, вчера! Нет проблем! Сейчас мы покажем, как создавать группы пользователей и учетные записи пользователей Windows NT, и как вносить нужных пользователей в нужные группы.

Если посмотреть на имена пользователей и группы вашего NT-сервера, легко заметить, что имеется несколько предварительно созданных групп, например, Administrators и Domain Users. Создать собственную группу на сервере или в домене несложно. Все, что требуется - указать Windows NT-компьютер, на котором вы собираетесь создавать группу и имя группы. В коде ниже демонстрируется пример функции CreateGroup, создающей такую группу. Чтобы получить ссылку на объект, с помощью которого можно управлять Active Directory, следует воспользоваться функцией GetObject. Воспользовавшись объектом, полученным от GetObject, можно добавить группу с нужным вам именем и ее описание. Важная строка кода - SetInfo, сохраняющая информацию на сервере:

sub CreateGroup (ServerName, GroupName, GroupDesc)
     on error resume next
     err.clear
     set objServer = GetObject("WinNT://" & ServerName)
     set objGroup = objServer.Create("group", GroupName)
     objGroup.Description = GroupDesc
     objGroup.SetInfo
     if err <&rt 0 then 
         WScript.Echo "Не могу создать группу " & GroupName
     Else
         Wscript.Echo "Группа " & GroupName & " создана успешно."
     end if
 end sub
 CreateGroup " YourServerName", "YourNewGroup", "Описание группы"

Если вы хотите создать группу в домене, а не на сервере, надо заменить ServerName на DomainName. Следует также привязываться не к серверному, а к доменному объекту.

Теперь, когда у вас есть собственная группа, давайте заведем несколько пользователей. Код на самом деле очень похож на код, создающий группу. Как и прежде, вам следует получить ссылку на серверный или доменный объект с помощью GetObject. Затем в коде создается пользователь и вводится некоторая информация, такую, как полное имя и пароль (пользователи могут изменить их при первом входе в систему или позже). Код в Листинге 5 создает трех пользователей и задает их пароли, полные имена и свойства загрузочного скрипта. По умолчанию Windows будет искать загрузочный скрипт в \\server\NETLOGON.

Листинг 5

sub CreateUser(ServerName, name, password, fullname, logonscript)
    on error resume next
    err.clear

    set objServer = GetObject("WinNT://" & ServerName)
    set objUser = objServer.Create ("user", name)
    objUser.Fullname = fullname
    objUser.setPassword password
    objUser.loginscript = logonscript
    objUser.SetInfo

    if err <> 0 then 
        WScript.Echo "Не могу создать учетную запись пользователя для" & name
    Else
        Wscript.Echo "Создана учетная запись пользователя: " & name
    end if
end sub

CreateUser "vernonh0", "Ivanoff", "abc123", "Ivanoff I.I.", "logon.wsf"
CreateUser "vernonh0", "Petroff", "abc123", "Petroff P.P.", "logon.wsf"
CreateUser "vernonh0", "Smirnoff", "abc123", "Smirnoff-Vodkin (Boss)", "logon.wsf"

Теперь вы готовы ввести пользователей в группы Windows NT. Хохмы ради добавим двух пользователей в свежесозданную группу, а одного - в группу администраторов.

sub AddUser (server, group, user)
     on error resume next
     err.clear
     set objGroup = GetObject("WinNT://" & server & "/" & group)
     objGroup.Add "WinNT://" & server & "/" & user
     if err <&rt 0 then 
         WScript.Echo "Не могу добавить" & user & " в группу " & group
     Else
         Wscript.Echo "Добавлен " & user & " в группу " & group
     end if
 end sub
 
 AddUser "YourServerName", "YourNewGroup", "Ivanoff"
 AddUser "YourServerName", "YourNewGroup", "Petroff"
 AddUser "YourServerName", "administrators", "Smirnoff"

Вывод

Windows Scripting Host - хорошая замена уходящим в прошлое BAT-файлам. Он уже имеет поддержку множества сторонних разработчиков, создающих новые скрипт-машины, хосты и т.д. С небольшим навыком программирования вы сможете писать собственные скрипты для автоматизации функций Windows. Если вы не сможете или не захотите писать нужный скрипт самостоятельно, почти наверняка такой найдется в Сети. Все это, поверьте, сделает вашу жизнь проще!

Это только верхушка айсберга - с помощью WSH, WMI и ADSI можно сделать куда больше. Windows Script Host позволяет писать независимые от языка скрипты с использованием его собственной объектной модели или какой-нибудь взятой взаймы. Так что будьте созидательны.

Преимущество в том, что вы сможете инкапсулировать всю эту функциональность в аккуратный COM-компонент, модуль, готовый к повторному использованию в любом приложении.

1.

Аноним

2 февраля 2006, 12:34:00

to robespier
Кроме shell у Юникса есть ещё перл,awk, python и т.д.

2.

Аноним

17 октября 2005, 17:22:24

А как скрипт определения и подключения пользователей выглядит в vba?

3.

Аноним

+2 / -1

5 июня 2005, 14:48:53

To duxa
В корне неправ! нельзя сравнивать две СОВЕРШЕННО разные вещи!
To all
WSH мошьнейшее средство для управления и администрирования Windows системм, которое позволяет получить доступ к изменению и настройке любой компоненты Windows вплоть до глубокого администрирования. При этом нет необходимости в использовании внешних приложений. Или запускать внешние пусть и системные утилиты, в отличие от Unix Shel -а который построен именно на этом.

4.

Аноним

+0 / -3

13 апреля 2005, 18:05:24

Когда это раньше единственным поддерживаемым языком был DOS? А какже cmd? И с каких это пор командный интерпретатор windows был хорошим средством автоматизации? Да и Windows Scripting Host мало что может (по крайней мере по сравнению с bash)